/*
 * CREDITS
 * ¯¯¯¯¯¯¯
 * MAIN SOURCE:
 *  Author:  Edgar Griñant
 *  Website: labs.grinant.com
 *
 * SOULWIRE CLASS:
 * Author:  Justin Windle
 * Website: soulwire.co.uk
 *
 * PAPERVISION3D CLASSES:
 *  Author:  Carlos Ulloa
 *  Website: blog.papervision3d.org
 *
 * INSPIRED BY QUASIMODO'S MINORITY CUBE (incubator.quasimondo.com/flash/minority_cube.php)
 */
 
package 
{
 // FLASH CLASSES
 import flash.display.Sprite;
 import flash.events.Event;
 import flash.media.Camera;
 import flash.media.Video;
 // SOULWIRE CLASS
 import com.soulwire.media.MotionTracker;
 // PAPERVISION3D CLASSES
 import org.papervision3d.cameras.Camera3D;
 import org.papervision3d.objects.primitives.Cube;
 import org.papervision3d.render.BasicRenderEngine;
 import org.papervision3d.scenes.Scene3D;
 import org.papervision3d.view.Viewport3D;
 import org.papervision3d.objects.DisplayObject3D;
 import org.papervision3d.materials.utils.MaterialsList;
 import org.papervision3d.core.proto.MaterialObject3D;
 import org.papervision3d.materials.BitmapFileMaterial;
 public class Main extends Sprite
 {
  /*______________
   ||PRIVATE VARS||
    ¯¯¯¯¯¯¯¯¯¯¯¯¯¯*/
  // SOULWIRE
  private var motionTracker :MotionTracker;
  
  // PAPERVISION
  private var viewport  :Viewport3D;
  private var scene   :Scene3D;
  private var camera   :Camera3D;
  private var cube   :Cube;
  private var renderer  :BasicRenderEngine;
  private var universe  :DisplayObject3D;
  
  /*_____________
   ||CONSTRUCTOR||
    ¯¯¯¯¯¯¯¯¯¯¯¯¯*/
  public function Main()
  {
   // PAPERVISION3D ENVIRONMENT
   init3D();
   createCube();
   // SOULWIRE MOTION TRACKING SETUP
   soulwire();
   // EVENT HANDLER ON ENTER FRAME (TRACK, ROTATE THE CUBE THEN RENDER)
   addEventListener( Event.ENTER_FRAME, track );
  }
  
  private function soulwire():void
  {
   // All of these variables can be changed to get a more acurate motion tracking
   var camW:Number = 320;
   var camH:Number = 240;
   var blur:Number = 20;
   var brightness:Number = 20;
   var contrast:Number = 150;
   var minArea:Number = 10;
 
   // Create the camera
   var cam:Camera = Camera.getCamera();
   cam.setMode( camW, camH, stage.frameRate );
   
   // Create a video
   var vid:Video = new Video( camW, camH );
   vid.attachCamera( cam );
   
   // Create the Motion Tracker
   motionTracker = new MotionTracker( vid );
   
   // We flip the input as we want a mirror image
   motionTracker.flipInput = true;
   
   // Apply some filters to ease the tracking
   motionTracker.blur = blur;
   motionTracker.brightness = brightness;
   motionTracker.contrast = contrast;
   motionTracker.minArea = minArea;
  }
  
  private function track( e:Event ):void
  {
   // Tell the MotionTracker to update itself
   motionTracker.track();
   
   // Rotate the cube
   cube.rotationY -= ((motionTracker.x ) + cube.rotationY) / 20;
   cube.rotationX -= ((motionTracker.y ) + cube.rotationX) / 20;
   
   // Render the scene
   renderer.renderScene(scene, camera, viewport);
  }
  
  private function init3D():void
  {
   // VIEWPORT
   viewport = new Viewport3D( 0, 0, true);
   addChild( viewport );
 
   // RENDERER
   renderer = new BasicRenderEngine();
 
   // SCENE
   scene = new Scene3D();
 
   // CAMERA
   camera = new Camera3D();
   camera.z = -1000;
   
   // UNIVERSE
   universe = new DisplayObject3D();
   scene.addChild(universe);
  }
  
  private function createCube():void
  {
   // Set the textures
   var materials:MaterialsList = new MaterialsList(
   {
    all: new BitmapFileMaterial("<a href="http://labs.grinant.com/uploads/2008/08/cube.png">http://labs.grinant.com/uploads/2008/08/cube.png</a>")
   });
   // Create the cube
   cube = new Cube(materials);
   universe.addChild(cube);
  }
  
 }
 
}

package {
 import flash.display.Sprite;
 import flash.display.DisplayObject;
 import flash.display.Stage;
 import flash.media.Video;
 import flash.media.Camera;
 import flash.filters.ConvolutionFilter;
 
 public class Main extends Sprite{
  // Init global variables
  var vid:Video;
  
  public function Main()
  {
   // Main actions
   setupCamera();
   applyFilter();
  }
  
  function setupCamera()
  {
   // Init camera.
   var cam:Camera = Camera.getCamera();
   // Create the video zone.
   vid = new Video();
   // Camera will be the source of the video.
   vid.attachCamera(cam);
   // Add the video object to the stage.
   addChild(vid);
   // Adjust the webcam picture to match width and height of the stage.
   vid.width = stage.stageWidth;
   vid.height = stage.stageHeight;
  }
  
  function applyFilter()
  {
   // Create the filter through a convolution matrix.
   // Create the matrix.
   var matrix:Array = [ -0.25, -3, -0.25,
         -3,    12,    -3,
         -0.25, -3, -0.25 ];
   // Create the ConvolutionFilter object.
   var convolution:ConvolutionFilter = new ConvolutionFilter();
   // Specify the lenght of the matrix.
   convolution.matrixX = 3;
   convolution.matrixY = 3;
   // Assign the matrix.
   convolution.matrix = matrix;
   convolution.divisor = 1;
   // Apply the filter.
   vid.filters = [convolution];
  }
 }
}